When you hover the cursor over the Minimize, Maximize, and Close buttons, on your Windows 2000 or Windows XP desktop, the ToolTips are displayed.

One reason to disable these ToolTips is that some 16-bit applications may experience access violations in WOW32.DLL when these ToolTips are enabled.

Using REG.EXE on Windows 2000 from the Windows 2000 Support Tools, and REG.EXE built into Windows XP, I have scripted UPM.BAT to remove these ToolTips.

You can run UPM.BAT individually, or use Workstation.bat to run them on all the Windows 2000 and Windows XP members of your domain.

UPM.BAT contains:

@echo off
if /i "%OS%" NEQ "Windows_NT" goto :EOF
for /f "Tokens=5 Delims=. " %%v in ('ver') do if "%%v" LSS "5" goto :EOF
setlocal
for /f "Skip=2 Tokens=3" %%u in ('reg QUERY "HKCU\Control Panel\Desktop" /v UserPreferencesmask') do set upm=%%u
set first=%upm:~0,1%
if /i "%first%" LSS "8" goto :default
if /i "%first%" EQU "8" set first=0&goto uwrite
if /i "%first%" EQU "9" set first=1&goto uwrite
if /i "%first%" EQU "a" set first=2&goto uwrite
if /i "%first%" EQU "b" set first=3&goto uwrite
if /i "%first%" EQU "c" set first=4&goto uwrite
if /i "%first%" EQU "d" set first=5&goto uwrite
if /i "%first%" EQU "e" set first=6
:uwrite
set remain=%upm:~1,7%
set upm=%first%%remain%
REG ADD "HKCU\Control Panel\Desktop" /v UserPreferencesmask /t REG_BINARY /d %upm% /f
:default
for /f "Skip=2 Tokens=3" %%u in ('reg QUERY "HKU\.Default\Control Panel\desktop" /v UserPreferencesmask') do set upm=%%u
set first=%upm:~0,1%
if /i "%first%" LSS "8" goto :done
if /i "%first%" EQU "8" set first=0&goto dwrite
if /i "%first%" EQU "9" set first=1&goto dwrite
if /i "%first%" EQU "a" set first=2&goto dwrite
if /i "%first%" EQU "b" set first=3&goto dwrite
if /i "%first%" EQU "c" set first=4&goto dwrite
if /i "%first%" EQU "d" set first=5&goto dwrite
if /i "%first%" EQU "e" set first=6
:dwrite
set remain=%upm:~1,7%
set upm=%first%%remain%
REG ADD "HKU\.Default\Control Panel\Desktop" /v UserPreferencesmask /t REG_BINARY /d %upm% /f
:done
endlocal